Passionate Software

A while back my old trusty FritzBox (PBX/router/fax/whatever) went south which actually was a good thing. Shopping for a new model I noticed that the newer versions of it (from 7170 onwards) support IP phones like the Snom IP phones I had lying around.

When I had separate office rooms I used an Asterisk (Trixbox, in fact) pbx and Snom phones with it. After a switched solely to FritzBox these Snom’s lied dormant- until now.

One thing I liked about the Asterisk solution was a quick way to dial a phone number from an address book. Back then I used Windows machines with Outlook and the free Asterisk Outlook Tapi plugin that was available.

Now the Fritzbox does not support click2dial for IP phone (at least I have not found this feature) but the Snom phone supports command URLs.

So the URL:

http://snom-user:snom-pw@snom-ip-address/command.htm?number=123456

will dial “123456″ from your phone.

Important Note: To make this work you must disable “Hidden Features” in the Snom QoS/Security settings (I use firmware version 8 with my Snom 360). If these are enabled then basically these action URLs don’t work.

Now you can test the above URL from any web browser and test you got this end working.

The other thing is the connection with Apple Addressbook.

For this I have copied an AppleScript from here and adapted to my needs:

(*
 Automatic SNOM Dialer v0.1
 Torsten Uhlmann, tuhlmann@agynamix.de
 based on Automatic Vonage Dialer by Aaron Freimark, abf@mac.com, March 16, 2004

 Put this script into your "Address Book Plugins" folder in your ~/Library folder.
 Only works in the US with this version

 *** YOU MUST Modify the first three lines below with your info ***
*)

property mySnomLogin : "username"
property mySnomPassword : "password"
property mySnomPhoneAddress : "ip-address"

using terms from application "Address Book"
        on action property
                return "phone"
        end action property
        
        on action title for pers with fone
                return "Dial with SNOM"
        end action title
        
        on should enable action for pers with fone
                if label of fone contains "fax" then return false
                return true
        end should enable action
        
        on perform action for pers with fone
                set numToDial to (value of fone) as string
                
                --Uncomment the following two lines to confirm the number
                --display dialog "So you want me to call?" default answer numToDial buttons {"OK"}
                --set numToDial to text returned of the result
                
                --Erase everything that's not a digit from the phone number
                set cleanedNumber to CleanTheNumber(numToDial)
                
                set theURL to "http://" & mySnomLogin & ":" & mySnomPassword & "@"
                set theURL to theURL & mySnomPhoneAddress & "/command.htm?number=" & cleanedNumber
                
                -- Use curl to hit the URL and dial the number  
                set errorCode to do shell script "curl \"" & theURL & "\""
                
                beep
                display dialog "Info: Dialing " & numToDial buttons {"OK"}
                
                --If there was an error, return a message.
                if (characters 1 thru 3 of errorCode) as string is not equal to "000" then
                        display dialog "Error: " & errorCode buttons {"OK"}
                end if
                
        end perform action
        
end using terms from

on CleanTheNumber(numToDial) -- remove punctuation from a string, leaving just the number
        set theDigits to {"0", "1", "2", "3", "4", "5", "6", "7", "8", "9"}
        set cleanedNumber to ""
        repeat with i from 1 to length of numToDial
                set j to (character i of numToDial)
                if j is in theDigits then set cleanedNumber to cleanedNumber & j
        end repeat
        return cleanedNumber
end CleanTheNumber

Open the AppleScript Editor and copy and paste the above script. Save the script into “Library/Address Book Plug-Ins” in your home directory. After you restart the address book application and left click on the text next to a phone number there should be a line in the appearing menu that reads “Dial with SNOM”.

Now click there and let the dial begin…

Enjoy,

Torsten.

{ 0 comments }